@echo off & setlocal enabledelayedexpansion
:: unprintable entry: ALT+digit_digit_digit  where digit is ONLY from numeric
:: keypad on right, not over-keys
::=================== LATER VERSION 2/13/13
::=========== LATEST 3/13/2015: added the "defpath" var. for DOFW.VBS handling
:: also finally got around to adding the "increment/decrement" feature which
:: I often need to use.
:: calnew only: also added a "zoom" feature!
:: everything works so far as tested, but the whole thing needs overhauled to
:: improve the layout.
::debug/display settings
set eko=rem 
set paz=rem
if "%2" neq "" (
set eko=echo
set paz=pause
)
set dz= %date:~7,2%%
set dz=%dz: 0=%
set defpath=%~dp0
set z=%1
set thisbat=%~n0.bat
::---- default size
set /a test=x+0
if %test% equ 0 set x=0
if %x% lss 3 set x=6

::--- help junk
if "%z%" equ "/?" set z=?
if "%z%" equ "-?" set z=?
if "%z%" equ "?" (
call :findline "--- END batch"
more +!n! %thisbat% |findstr /e /c:" "
goto :eof
)

::--- dofw junk
rem if /I "%z%" equ "dofw" (
if not exist %defpath%\dofw.vbs (
call :findline "--- END helpfile"
echo building %defpath%\dofw.vbs from %defpath%\%thisbat% line !n!:
pause
more +!n! %defpath%\%thisbat%> %defpath%\dofw.vbs
echo done.
rem goto :eof
)


:top
rem set L1=ÚÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄ¿
rem set L2=ÃÄÄÄÄÄÄÅÄÄÄÄÄÄÅÄÄÄÄÄÄÅÄÄÄÄÄÄÅÄÄÄÄÄÄÅÄÄÄÄÄÄÅÄÄÄÄÄÄ´
rem set L3=ÀÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÙ
rem set blank=³      ³      ³      ³      ³      ³      ³      ³
call :build
set months=JANUARY  FEBRUARY MARCH    APRIL    MAY      JUNE     JULY     AUGUST   SEPTEMBEROCTOBER  NOVEMBER DECEMBER
set thirty=" 4 6 9 11 "

::if %x% equ 3 (set days= )
:--- date
:--- attempt to allow override of current-date-default via vbscript
:startnext
%eko% starnext z:%z% !z!
if not defined z set z=%1
if "%z%" neq "" (
for /f "tokens=1-3 delims=/-." %%a in ("%z%") do if "%%c" equ "" set z=%%a/%dz%/%%b
set /p=Submitting date: !z! to dofw.vbs...<nul
for /f "tokens=*" %%a in ('cscript /Nologo %defpath%\dofw.vbs !z!') do set dd=%%a
echo. Date returned from dofw: !dd!
) else (
set aster=*
set dd=%date%
:: enable for foll. manual override/testing
rem set /p dd=date:
)
for /f "tokens=1-4 delims=-/ " %%a in ("%dd%") do (
set day= %%c
set mo= %%b
set yr=%%d
set dofw=%%a
)
set mo=%mo: 0= %
set mo=%mo: =%
set day=%day: 0=%
if "%yr:~2%" equ "" set yr=20%yr%
%eko% DAY %day%
%eko% dofw: %dofw%:
%paz%
:--- establish length of month
%eko% mo:%mo%
set eom=31
set test=!thirty: %mo% =**!
%eko% test: %test% %thirty%
if %test% neq %thirty% set eom=30
rem echo %thirty% %test%
%paz%
if "%mo%" equ "2" (
set /a test="yr%%4"
if !test! equ 0 (set eom=29) else (set eom=28)
)
%eko% eom: %eom%
%paz%
:--- setup formal (display) month
set /a test=(mo-1)*9
set month=!months:~%test%,9!
:--- establish day-of-week
set c=0
for %%i in (%days%) do (if /i %dofw% equ %%i (goto :gout) else (set /a c+=1))

echo ???????? problem here!!
goto :eof
:gout
:--- establish dofw of the first of the month
%eko% day: %day%
%eko% dofw {0=sunday}: %c%
set /a offs=c-"(day-1)%%7"
set /a first="(7-((day-1)%%7)+c)%%7-1"
%eko% offs: %offs%
%eko% first: %first%
%paz%
:display
(set e= %t%  )
set ee=%bar%
%eko% first: %first%
for /L %%i in (0,1,%first%) do set ee=!ee!%e%%bar%
echo.
(set sp= )
set sep=%L2%
:*********** D I S P L A Y   S T A R T
rem echo                    %month% %yr%
echo %pad%%month% %yr%
echo.
echo %days%
echo %L1%
:*********** M A I N   L O O P

for /L %%i in (1,1,%eom%) do (
if %%i gtr 9 set sp=
(set tag= )
if %%i equ %dz% set tag=%aster%
set ee=!ee!!sp!!t!!tag!%%i%bar%
set /a u="(%%i+offs)%%7"
if !u! equ 0 (
if %%i equ %eom% set sep=%L3%
%paz%
call :box
set ee=%bar%
)
)
if %sep% equ %L3% goto :getnext
set sep=%L3%
for /L %%i in (%u%,1,6) do set ee=!ee!%e%%bar%
call :box

:getnext
set zz=
set /p zz=next date like MM.YY or M-YY or M/YY, or p/n to incr/decr, +/- zoom:
if not defined zz goto :eof
if /i %zz% equ + (
set /a x+=1
call :build
goto :display
)
if /i %zz% equ - (
set /a x-=1
call :build
goto :display
)
if /i %zz% equ N set zz=+
if /i %zz% equ P set zz=-
if "%zz%" equ "+" (
set /a mo+=1
if !mo! equ 13 (
set mo=1
set /a yr+=1
)
set zz=!mo!/1/!yr!
)
if "%zz%" equ "-" (
set /a mo-=1
if !mo! equ 0 (
set mo=12
set /a yr-=1
)
set zz=!mo!/1/!yr!
)
set z=%zz%
goto :startnext

:box
echo !ee!
for /L %%g in (1,1,%height%) do (
echo %blank%
)
echo %sep%
goto :eof

:findline
for /f "tokens=1-2 delims=[]" %%a in ('find /i /n %1 ^<%thisbat%') do set n=%%a
goto :eof

:build
set days=
set t=
set tt=0
set L1=Ú
set L2=Ã
set L3=À
set bar=³
set blank=%bar%
for /L %%b in (1 1 7) do (
for /L %%a in (1 1 %x%) do (
set L1=!L1!Ä
SET L2=!L2!Ä
SET L3=!L3!Ä
(SET blank=!blank! )
if %%b equ 7 (
(set t=!t! )
set /a tt+=1
)
)
set blank=!blank!%bar%
if %%b lss 7 (
set L1=!L1!Â
SET L2=!L2!Å
SET L3=!L3!Á
) else (
set L1=!L1!¿
SET L2=!L2!´
SET L3=!L3!Ù
)
)
set t=%t:~0,-3%
set /a tx=(tt-3)/2
%eko% t:!t!:!tt!:!tx!:
REM (set aster= )
:heighth of each cell
set /a height=tt/2
for %%b in (Sun    Mon    Tue    Wed    Thu    Fri    Sat) do (
set days=!days!%t%%%b )
)
set /a tx=tt/3
if %tt% lss 8 set /a tx-=1
set days=!days:~%tx%!
(set pad=                                                           )
set /a xx=(x-1)*4
set pad=!pad:~0,%xx%!
%eko% pad:%pad%:
%eko% sub. BUILD, days: %days%
%paz% pause
goto :eof

:be sure to leave at least one space at end of each of the "help" lines,
:since that's how they are extracted by "findstr" for display.
:So, if you add or change a line, always put a trailing space.
:Also, leave the following relatively intact (see ":findline" sub)
:------------------ END BATCH, begin helpfile
Calendr.bat can generate/display a calendar of the current month unassisted,  
but to generate other months, it needs the help of the included file  
"dofw.vbs" to do the date-math required to determine the day-of-week  
offset of the non-current dates. The calendr output can be piped out to a 
file for printing etc.  
To use the non-current-date extension, you can use MORE to create the vbs  
file. Just run the following from the command-prompt:  
                   MORE +nnn calendr.bat > dofw.vbs  
or, preferably (and more reliably), you can do this from the command-prompt:  
                   CALENDR DOFW  
And the batchfile will create the vbscript, after which Calendr could now  
process a command-line date-modifier (mm-yy), like (for Jan 2012):  
  CALENDR 1/12  or: CALENDR 1-12  or: CALENDR 1.12  
(dashes and slashes dots are interchangeable as delimiters.  
You can include the day, but it's ignored as being irrelevant)  

Once launched, you can increment or decrement the calendar using n/p.  
And you can zoom in (enlarge) or zoom out (reduce) using +/- resp.  

please report any errors/ommissions/bugs/suggestions via email:  
kitpackers@suddenlink.net  

:------------------ END helpfile, begin vbscript "dofw.vbs"
'obtain day-of-week of given input date, output like: Sun 1/2/2012
set y=wscript.arguments
a=y.count-1
if a < 0 then x=date else x=y(0)
dofw=left(FormatDateTime(x,1),3)
test=FormatDateTime(x,0)
wscript.stdout.write(dofw+" "+test)